viewvc.cgi/VRac/Screen.pm

package Screen;

# Dobrica Pavlinusic, <dpavlin@rot13.org> 07/30/07 17:58:55 CEST

use strict;
use warnings;

use SDL::App;
use SDL::Rect;
use SDL::Color;
use SDL::Constants;

use Carp qw/confess/;
use Data::Dump qw/dump/;

use Exporter 'import';
our @EXPORT = qw'$white $black @flip';

use base qw(Class::Accessor Prefs);
__PACKAGE__->mk_accessors(qw(app event screen_width screen_height));

=head1 NAME

Screen - simulated monochrome screen using SDL

=head1 Architecture dependent

You may override following methods if you want to implement keyboard on each
keypress event. Alternative is to use <read> hook and trap memory access.

=head2 screen_width

Width of emulated screen (256 by default)

=head2 screen_height

Height of emulated screen (256 by default)

=head2 key_down

  $self->key_down( 'a' );

=cut

sub key_down {}

=head2 key_up

  $self->key_up( 'a' );

=cut

sub key_up {}


=head1 Architecture independent

You don't need to override any of following function in your architecture,
but you might want to call them.

=head2 open_screen

Open simulated screen

=cut

our $app;

sub open_screen {
        my $self = shift;

        $self->prefs;

        if ( ! $self->scale ) {
                $self->scale( 1 );
                warn "using default unscaled display\n";
        }

        $self->screen_width( 256 ) unless defined $self->screen_width;
        $self->screen_height( 256 ) unless defined $self->screen_height;

        $app = SDL::App->new(
                -width  => $self->screen_width * $self->scale + ( $self->show_mem ? 256 : 0 ),
                -height => $self->screen_height * $self->scale,
                -depth  => 16,
                -flags=>SDL_DOUBLEBUF | SDL_HWSURFACE | SDL_HWACCEL,
        );
        #$app->grab_input( SDL_GRAB_QUERY );
        $app->grab_input( SDL_GRAB_OFF );
        $app->title( ref($self) );

        $self->app( $app );

        my $event = SDL::Event->new();
        $self->event( $event );

        warn "# created SDL::App with screen ", $self->screen_width, "x", $self->screen_height, "\n";
}

our $white      = SDL::Color->new( -r => 0xff, -g => 0xff, -b => 0xff );
our $black      = SDL::Color->new( -r => 0x80, -g => 0x80, -b => 0x80 );

my $red         = SDL::Color->new( -r => 0xff, -g => 0x00, -b => 0x00 );
my $green       = SDL::Color->new( -r => 0x00, -g => 0xff, -b => 0x00 );
my $blue        = SDL::Color->new( -r => 0x00, -g => 0x00, -b => 0xff );

=head2 mem_xy

Helper to return x and y coordinates in memory map

  my ( $x,$y ) = $screen->mem_xy( $address );

=cut

sub mem_xy {
        my $self = shift;
        my $offset = shift;
        my $x = $offset & 0xff;
        $x += $self->screen_width * $self->scale;
        my $y = $offset >> 8;
        return ($x,$y);
}

=head2 mmap_pixel

Draw pixel in memory map

  $self->mmap_pixel( $addr, $r, $g, $b );

=cut

# keep accesses to memory
my $_mem_stat;

sub mmap_pixel {
        my ( $self, $addr, $r, $g, $b ) = @_;
        return unless $self->show_mem && $self->app;

        my ( $x, $y ) = $self->mem_xy( $addr );
        warn sprintf "## mem %04x %02x %02x %02d*%02d\n", $addr, $r, $g, $x, $y if $self->debug;

        my $col = SDL::Color->new( -r => $r, -g => $g, -b => $b );
        $self->app->pixel( $x, $y, $col );

        $_mem_stat++;
        if ( $_mem_stat % 1000 == 0 ) {
                $self->app->sync;
        }
}


=head2 sync

  $self->sync;

=cut

sub sync {
        $app->sync;
}

=head2 render_vram

Render one frame of video ram

  $self->render_vram;

=cut

sub render_vram {
        my $self = shift;

        confess "please implement $self::render_vram";
}


=head2 render_frame

Render one frame of video ram

  $self->render_frame( $vram_sdl_surface );

=cut

sub render_frame {
        my $self = shift;

        my $vram = shift;
        confess "need SDL::Surface as argument" unless ref($vram) eq 'SDL::Surface';

        $vram->display_format;

        my $scale = $self->scale || confess "no scale?";

        my $rect        = SDL::Rect->new( -x => 0, -y => 0, -width => $self->screen_width * $scale, -height => $self->screen_height * $scale
        );
        my $rect_screen = SDL::Rect->new( -x => 0, -y => 0, -width => $self->screen_width * $scale, -height => $self->screen_height * $scale );

        if ( $scale > 1 ) {
                use SDL::Tool::Graphic;
                # last parametar is anti-alias
                my $zoomed = SDL::Tool::Graphic->zoom( $vram, $self->scale, $self->scale, 1 );
                $zoomed->blit( $rect, $app, $rect_screen );
        } else {
                $vram->blit( $rect, $app, $rect_screen );
        }

        $app->sync;
}


=head2 render_mem

  $self->render_mem( @mem );

=cut

sub render_mem {
        my $self = shift;

        return unless $self->show_mem;

        my $pixels = pack("C*", @_);

        my $vram = SDL::Surface->new(
                -width => 256,
                -height => 256,
                -depth => 8,    # 1 bit per pixel
                -pitch => 256,  # bytes per line
                -from => $pixels,
                -Rmask => 0xffff00ff,
                -Gmask => 0xffff00ff,
                -Bmask => 0xffff00ff,
        );

        $vram->display_format;

        my $rect     = SDL::Rect->new( -x => 0, -y => 0, -width => $self->screen_width, -height => $self->screen_height );
        my $rect_mem = SDL::Rect->new( -x => $self->screen_width * $self->scale, -y => 0, -width => 256, -height => 256 );

        $vram->blit( $rect, $app, $rect_mem );

        $app->sync;
}

=head2 key_pressed

Check SDL event loop if there are any pending keys

  my $key = $self->key_pressed;

  if ( $self->key_pressed( 1 ) ) {
        # just to check other events, don't process
        # key
  }

=cut

my $pending_key;
my $key_active;
my $run_for = 2000;

sub key_pressed {
        my $self = shift;

        # don't take key, just pull event
        my $just_checking = shift || 0;

        my $event = $self->event || confess "no event?";

        if ( ! $event->poll ) {
                return $pending_key unless $self->can('session_event');
                if ( my $h = $self->session_event('key_pressed') ) {
                        my ( $key, $state ) = %$h;
                        if ( $state ) {
                                $pending_key = $key;
                                $self->key_down( $key );
                                $key_active->{$key} = 1;
                        } else {
                                undef $pending_key;
                                $self->key_up( $key );
                                $key_active->{$key} = 0;
                        }
                }
                return $pending_key;
        }

        my $type = $event->type();

        exit if ($type == SDL_QUIT);

        my $k = $pending_key;

        if ($type == SDL_KEYDOWN) {
                $k = $event->key_name();
                if ( $k eq 'escape' ) {
                        $run_for = $self->cli;
                        warn "will check event loop every $run_for cycles\n";
                        $pending_key = '~';
                } else {
                        warn "SDL_KEYDOWN ($type) = '$k'", $just_checking ? ' fake' : '', "\n";
                        $pending_key = $k;
                        $self->key_down( $k );
                        $key_active->{$k} = 1;
                        $self->record_session('key_pressed', { $k => 1 });
                }
        } elsif ( $type == SDL_KEYUP ) {
                my $up = $event->key_name();
                warn "SDL_KEYUP ($type) = '$up'", $just_checking ? ' fake' : '', "\n";
                $self->key_up( $up );
                $key_active->{$up} = 0;
                $self->record_session('key_pressed', { $up => 0 });
                undef $pending_key;
        }

        warn "key_pressed = $pending_key\n" if ( $pending_key );

        return $pending_key;
}

=head2 key_active

Is key currently pressed on keyboard or in session?

  $self->key_active( 'left shift', 'right shift', 'a' );

=cut

sub key_active {
        my $self = shift;
        my @keys = @_;
        confess "Regexp is no longer supported" if ref($_[0]) eq 'Regexp';

        my $active = 0;
        foreach my $key ( @keys ) {
                $active++ if $key_active->{$key};
        }

        warn "## key_active(",dump(@keys),") = $active\n" if $active;
        return $active;
}

=head2 loop

Implement CPU run for C<$run_run> cycles inside SDL event loop

  $self->loop( sub {
        my $run_for = shift;
        CPU::exec( $run_for );
        $self->render_vram;
  } );

=cut

sub loop {
        my $self = shift;
        my $exec = shift;

        confess "need coderef as argument" unless ref($exec) eq 'CODE';
        my $event = SDL::Event->new();

        while ( 1 ) {
                $self->key_pressed( 1 );
                $exec->($run_for);
        }
}

# helper array to flip bytes for display
our @flip;

foreach my $i ( 0 .. 255 ) {
        my $t = 0;
        $i & 0b00000001 and $t = $t | 0b10000000;
        $i & 0b00000010 and $t = $t | 0b01000000;
        $i & 0b00000100 and $t = $t | 0b00100000;
        $i & 0b00001000 and $t = $t | 0b00010000;
        $i & 0b00010000 and $t = $t | 0b00001000;
        $i & 0b00100000 and $t = $t | 0b00000100;
        $i & 0b01000000 and $t = $t | 0b00000010;
        $i & 0b10000000 and $t = $t | 0b00000001;
        #warn "$i = $t\n";
        $flip[$i] = $t;
}

=head1 SEE ALSO

L<Orao> is sample implementation using this module

=head1 AUTHOR

Dobrica Pavlinusic, C<< <dpavlin@rot13.org> >>

=head1 COPYRIGHT & LICENSE

Copyright 2007 Dobrica Pavlinusic, All Rights Reserved.

This program is free software; you can redistribute it and/or modify it
under the same terms as Perl itself.

=cut

1;
1	dpavlin	29	package Screen;
2
3			# Dobrica Pavlinusic, <dpavlin@rot13.org> 07/30/07 17:58:55 CEST
4
5			use strict;
6			use warnings;
7
8			use SDL::App;
9			use SDL::Rect;
10			use SDL::Color;
11	dpavlin	75	use SDL::Constants;
12	dpavlin	29
13	dpavlin	33	use Carp qw/confess/;
14	dpavlin	75	use Data::Dump qw/dump/;
15	dpavlin	33
16	dpavlin	125	use Exporter 'import';
17	dpavlin	165	our @EXPORT = qw'$white $black @flip';
18	dpavlin	125
19	dpavlin	56	use base qw(Class::Accessor Prefs);
20	dpavlin	183	__PACKAGE__->mk_accessors(qw(app event screen_width screen_height));
21	dpavlin	29
22	dpavlin	55	=head1 NAME
23
24	dpavlin	183	Screen - simulated monochrome screen using SDL
25	dpavlin	55
26	dpavlin	161	=head1 Architecture dependent
27
28			You may override following methods if you want to implement keyboard on each
29			keypress event. Alternative is to use <read> hook and trap memory access.
30
31	dpavlin	183	=head2 screen_width
32
33			Width of emulated screen (256 by default)
34
35			=head2 screen_height
36
37			Height of emulated screen (256 by default)
38
39	dpavlin	161	=head2 key_down
40
41			$self->key_down( 'a' );
42
43			=cut
44
45			sub key_down {}
46
47			=head2 key_up
48
49			$self->key_up( 'a' );
50
51			=cut
52
53			sub key_up {}
54
55
56			=head1 Architecture independent
57
58			You don't need to override any of following function in your architecture,
59			but you might want to call them.
60
61	dpavlin	30	=head2 open_screen
62	dpavlin	29
63			Open simulated screen
64
65			=cut
66
67			our $app;
68
69	dpavlin	30	sub open_screen {
70	dpavlin	29	my $self = shift;
71	dpavlin	31
72	dpavlin	56	$self->prefs;
73
74	dpavlin	31	if ( ! $self->scale ) {
75			$self->scale( 1 );
76			warn "using default unscaled display\n";
77			}
78
79	dpavlin	183	$self->screen_width( 256 ) unless defined $self->screen_width;
80			$self->screen_height( 256 ) unless defined $self->screen_height;
81
82	dpavlin	29	$app = SDL::App->new(
83	dpavlin	183	-width => $self->screen_width * $self->scale + ( $self->show_mem ? 256 : 0 ),
84			-height => $self->screen_height * $self->scale,
85	dpavlin	29	-depth => 16,
86	dpavlin	142	-flags=>SDL_DOUBLEBUF \| SDL_HWSURFACE \| SDL_HWACCEL,
87	dpavlin	29	);
88	dpavlin	75	#$app->grab_input( SDL_GRAB_QUERY );
89			$app->grab_input( SDL_GRAB_OFF );
90	dpavlin	155	$app->title( ref($self) );
91	dpavlin	29
92	dpavlin	98	$self->app( $app );
93
94			my $event = SDL::Event->new();
95			$self->event( $event );
96
97	dpavlin	183	warn "# created SDL::App with screen ", $self->screen_width, "x", $self->screen_height, "\n";
98	dpavlin	29	}
99
100	dpavlin	125	our $white = SDL::Color->new( -r => 0xff, -g => 0xff, -b => 0xff );
101			our $black = SDL::Color->new( -r => 0x80, -g => 0x80, -b => 0x80 );
102	dpavlin	29
103			my $red = SDL::Color->new( -r => 0xff, -g => 0x00, -b => 0x00 );
104			my $green = SDL::Color->new( -r => 0x00, -g => 0xff, -b => 0x00 );
105			my $blue = SDL::Color->new( -r => 0x00, -g => 0x00, -b => 0xff );
106
107			=head2 mem_xy
108
109			Helper to return x and y coordinates in memory map
110
111			my ( $x,$y ) = $screen->mem_xy( $address );
112
113			=cut
114
115			sub mem_xy {
116			my $self = shift;
117			my $offset = shift;
118			my $x = $offset & 0xff;
119	dpavlin	183	$x += $self->screen_width * $self->scale;
120	dpavlin	29	my $y = $offset >> 8;
121			return ($x,$y);
122			}
123
124	dpavlin	32	=head2 mmap_pixel
125
126			Draw pixel in memory map
127
128			$self->mmap_pixel( $addr, $r, $g, $b );
129
130			=cut
131
132			# keep accesses to memory
133			my $_mem_stat;
134
135			sub mmap_pixel {
136			my ( $self, $addr, $r, $g, $b ) = @_;
137	dpavlin	33	return unless $self->show_mem && $self->app;
138	dpavlin	32
139	dpavlin	33	my ( $x, $y ) = $self->mem_xy( $addr );
140	dpavlin	41	warn sprintf "## mem %04x %02x %02x %02d*%02d\n", $addr, $r, $g, $x, $y if $self->debug;
141	dpavlin	32
142	dpavlin	33	my $col = SDL::Color->new( -r => $r, -g => $g, -b => $b );
143			$self->app->pixel( $x, $y, $col );
144	dpavlin	32
145			$_mem_stat++;
146			if ( $_mem_stat % 1000 == 0 ) {
147	dpavlin	33	$self->app->sync;
148	dpavlin	32	}
149			}
150
151	dpavlin	33
152			=head2 sync
153
154			$self->sync;
155
156			=cut
157
158			sub sync {
159			$app->sync;
160			}
161
162	dpavlin	107	=head2 render_vram
163	dpavlin	73
164	dpavlin	76	Render one frame of video ram
165
166	dpavlin	126	$self->render_vram;
167	dpavlin	73
168			=cut
169
170	dpavlin	125	sub render_vram {
171			my $self = shift;
172	dpavlin	107
173	dpavlin	125	confess "please implement $self::render_vram";
174	dpavlin	107	}
175
176
177	dpavlin	125	=head2 render_frame
178	dpavlin	73
179	dpavlin	125	Render one frame of video ram
180	dpavlin	106
181	dpavlin	125	$self->render_frame( $vram_sdl_surface );
182	dpavlin	106
183	dpavlin	125	=cut
184	dpavlin	107
185	dpavlin	125	sub render_frame {
186			my $self = shift;
187
188			my $vram = shift;
189			confess "need SDL::Surface as argument" unless ref($vram) eq 'SDL::Surface';
190
191	dpavlin	75	$vram->display_format;
192	dpavlin	73
193	dpavlin	125	my $scale = $self->scale \|\| confess "no scale?";
194	dpavlin	73
195	dpavlin	183	my $rect = SDL::Rect->new( -x => 0, -y => 0, -width => $self->screen_width * $scale, -height => $self->screen_height * $scale
196			);
197			my $rect_screen = SDL::Rect->new( -x => 0, -y => 0, -width => $self->screen_width * $scale, -height => $self->screen_height * $scale );
198	dpavlin	121
199			if ( $scale > 1 ) {
200			use SDL::Tool::Graphic;
201			# last parametar is anti-alias
202			my $zoomed = SDL::Tool::Graphic->zoom( $vram, $self->scale, $self->scale, 1 );
203			$zoomed->blit( $rect, $app, $rect_screen );
204			} else {
205			$vram->blit( $rect, $app, $rect_screen );
206			}
207
208	dpavlin	73	$app->sync;
209			}
210
211	dpavlin	125
212	dpavlin	76	=head2 render_mem
213
214	dpavlin	126	$self->render_mem( @mem );
215	dpavlin	76
216			=cut
217
218			sub render_mem {
219			my $self = shift;
220
221			return unless $self->show_mem;
222
223			my $pixels = pack("C*", @_);
224
225			my $vram = SDL::Surface->new(
226			-width => 256,
227			-height => 256,
228			-depth => 8, # 1 bit per pixel
229			-pitch => 256, # bytes per line
230			-from => $pixels,
231			-Rmask => 0xffff00ff,
232			-Gmask => 0xffff00ff,
233			-Bmask => 0xffff00ff,
234			);
235
236			$vram->display_format;
237
238	dpavlin	183	my $rect = SDL::Rect->new( -x => 0, -y => 0, -width => $self->screen_width, -height => $self->screen_height );
239			my $rect_mem = SDL::Rect->new( -x => $self->screen_width * $self->scale, -y => 0, -width => 256, -height => 256 );
240	dpavlin	143
241	dpavlin	76	$vram->blit( $rect, $app, $rect_mem );
242
243			$app->sync;
244			}
245
246	dpavlin	98	=head2 key_pressed
247
248			Check SDL event loop if there are any pending keys
249
250			my $key = $self->key_pressed;
251
252			if ( $self->key_pressed( 1 ) ) {
253			# just to check other events, don't process
254			# key
255			}
256
257			=cut
258
259			my $pending_key;
260	dpavlin	171	my $key_active;
261	dpavlin	98	my $run_for = 2000;
262
263			sub key_pressed {
264			my $self = shift;
265
266			# don't take key, just pull event
267	dpavlin	101	my $just_checking = shift \|\| 0;
268	dpavlin	98
269			my $event = $self->event \|\| confess "no event?";
270
271	dpavlin	150	if ( ! $event->poll ) {
272	dpavlin	155	return $pending_key unless $self->can('session_event');
273	dpavlin	150	if ( my $h = $self->session_event('key_pressed') ) {
274			my ( $key, $state ) = %$h;
275			if ( $state ) {
276			$pending_key = $key;
277	dpavlin	161	$self->key_down( $key );
278	dpavlin	171	$key_active->{$key} = 1;
279	dpavlin	150	} else {
280			undef $pending_key;
281	dpavlin	161	$self->key_up( $key );
282	dpavlin	171	$key_active->{$key} = 0;
283	dpavlin	150	}
284			}
285			return $pending_key;
286			}
287	dpavlin	98
288			my $type = $event->type();
289
290			exit if ($type == SDL_QUIT);
291
292	dpavlin	99	my $k = $pending_key;
293	dpavlin	98
294			if ($type == SDL_KEYDOWN) {
295			$k = $event->key_name();
296			if ( $k eq 'escape' ) {
297			$run_for = $self->cli;
298			warn "will check event loop every $run_for cycles\n";
299	dpavlin	101	$pending_key = '~';
300	dpavlin	98	} else {
301	dpavlin	101	warn "SDL_KEYDOWN ($type) = '$k'", $just_checking ? ' fake' : '', "\n";
302			$pending_key = $k;
303	dpavlin	161	$self->key_down( $k );
304	dpavlin	171	$key_active->{$k} = 1;
305	dpavlin	150	$self->record_session('key_pressed', { $k => 1 });
306	dpavlin	98	}
307			} elsif ( $type == SDL_KEYUP ) {
308			my $up = $event->key_name();
309	dpavlin	150	warn "SDL_KEYUP ($type) = '$up'", $just_checking ? ' fake' : '', "\n";
310	dpavlin	161	$self->key_up( $up );
311	dpavlin	171	$key_active->{$up} = 0;
312	dpavlin	150	$self->record_session('key_pressed', { $up => 0 });
313	dpavlin	99	undef $pending_key;
314	dpavlin	98	}
315
316	dpavlin	150	warn "key_pressed = $pending_key\n" if ( $pending_key );
317	dpavlin	99
318			return $pending_key;
319	dpavlin	98	}
320
321	dpavlin	171	=head2 key_active
322
323			Is key currently pressed on keyboard or in session?
324
325			$self->key_active( 'left shift', 'right shift', 'a' );
326
327			=cut
328
329			sub key_active {
330			my $self = shift;
331			my @keys = @_;
332			confess "Regexp is no longer supported" if ref($_[0]) eq 'Regexp';
333
334			my $active = 0;
335			foreach my $key ( @keys ) {
336			$active++ if $key_active->{$key};
337			}
338
339			warn "## key_active(",dump(@keys),") = $active\n" if $active;
340			return $active;
341			}
342
343	dpavlin	96	=head2 loop
344
345	dpavlin	126	Implement CPU run for C<$run_run> cycles inside SDL event loop
346	dpavlin	96
347	dpavlin	126	$self->loop( sub {
348			my $run_for = shift;
349			CPU::exec( $run_for );
350			$self->render_vram;
351			} );
352
353	dpavlin	96	=cut
354
355			sub loop {
356			my $self = shift;
357	dpavlin	126	my $exec = shift;
358
359			confess "need coderef as argument" unless ref($exec) eq 'CODE';
360	dpavlin	96	my $event = SDL::Event->new();
361
362			while ( 1 ) {
363	dpavlin	98	$self->key_pressed( 1 );
364	dpavlin	126	$exec->($run_for);
365	dpavlin	96	}
366			}
367
368	dpavlin	165	# helper array to flip bytes for display
369			our @flip;
370
371			foreach my $i ( 0 .. 255 ) {
372			my $t = 0;
373			$i & 0b00000001 and $t = $t \| 0b10000000;
374			$i & 0b00000010 and $t = $t \| 0b01000000;
375			$i & 0b00000100 and $t = $t \| 0b00100000;
376			$i & 0b00001000 and $t = $t \| 0b00010000;
377			$i & 0b00010000 and $t = $t \| 0b00001000;
378			$i & 0b00100000 and $t = $t \| 0b00000100;
379			$i & 0b01000000 and $t = $t \| 0b00000010;
380			$i & 0b10000000 and $t = $t \| 0b00000001;
381			#warn "$i = $t\n";
382			$flip[$i] = $t;
383			}
384
385	dpavlin	55	=head1 SEE ALSO
386
387			L<Orao> is sample implementation using this module
388
389			=head1 AUTHOR
390
391			Dobrica Pavlinusic, C<< <dpavlin@rot13.org> >>
392
393			=head1 COPYRIGHT & LICENSE
394
395			Copyright 2007 Dobrica Pavlinusic, All Rights Reserved.
396
397			This program is free software; you can redistribute it and/or modify it
398			under the same terms as Perl itself.
399
400			=cut
401	dpavlin	148
402	dpavlin	32	1;