viewvc.cgi/PLies/burst.pl

#!/usr/bin/perl
#
# PLies Copyright 2001 Dobrica Pavlinusic <dpavlin@rot13.org>
#
# this tool is based on SlideMaker and XLSies tool
# split a all.htm into slide*.htm
#
# For more information please see presentation about this tool on
# http://www.rot13.org/~dpavlin/presentations/XLSies_to_PLies/
#
# Copyright 1999 World Wide Web Consortium,
# (Massachusetts Institute of Technology, Institut
# National de Recherche en Informatique et en
# Automatique, Keio University). All Rights Reserved.
# This program is distributed under the W3C's
# Intellectual Property License. This program is
# distributed in the hope that it will be useful, but
# WITHOUT ANY WARRANTY; without even the implied
# warranty of MERCHANTABILITY or FITNESS FOR A
# PARTICULAR PURPOSE. See W3C License
# http://www.w3.org/Consortium/Legal/ for more details.
#
#
##############################################################################
#
# slidemaker credits:
#
# Stephan Montigaud - stephan@w3.org
# created 970601
# modified by Pierre Fillault
# check the documentation at http://www.w3.org/Talks/YYMMsub/
#
# modified 19990505 Bert Bos: ALT text of prev/next arrows is now
# "prev"/"next" rather than the title of the prev/next slide; looks better
# in lynx.
#
# version: 4.14 - 19990719
# $Id: w3cburst.pl,v 1.41 1999/11/02 17:25:50 charles Exp $
#
#
# XLSies credits:
#
# Sami Lempinen - lempinen@iki.fi
# http://www.snowman.sgic.fi/ssl/xslies/
#
# Text::FastTemplate:
# Robert Lehr - bozzio@the-lehrs.com

use Text::FastTemplate;

##############################################################################
## default values of variables
##

## show debug output
my $debug=1;

## default DOCTYPE added on the slides
$doctype = '<html xmlns="http://www.w3.org/TR/REC-html40">';

## name of raw HTML file containing the slides
$all = 'all.htm';

## table of content built from all.htm - also first page of the presentation
## this is only the basename as we need to generate one toc for each style sheets
## the main toc will not bear any more so the server can understand a request for '/'
## the next ones will bear a number corresponding to the slide index
#$overview = 'Overview';
$overview = 'index';

## name of the file containing the parameters of the presentation
$infos = 'infos.txt';

## link to the logo printed on all the slides
$logoLink = '';

## default location of the logo - works when slidemaker is used as a package
$logoFile = '';

### localization
$loc_toc = "Table of contents";
$loc_by = "by";
$loc_amp = "&amp;";     # author separator
$loc_slide = "Slide";
$loc_of = "of";         # $loc_slide nr $loc_of total

## alternate representation of the logo
$logoAlt = '';

## default values set to none
$logoLink2 = '';     # link to a potential second reference
$logoFile2 = '';     # location of a second logo
$logoAlt2  = '';     # alternate representation of the second logo

## default accesskeys for navigation icons used in the slides
$prevKey  = 'P';        # accesskey for previous slide
$nextKey  = 'N';        # accesskey for next slide
$tocKey   = 'C';        # accesskey for table of contents
$styleKey = 'S';        # accesskey for changing style sheets

## default author name
$author = 'Staff';

## default presentation title
$talkTitle = 'Talk';

## standard style sheets 
$cssStandard = '../PLies/css/default.css';

## template name
$template = '../PLies/default';

## default charset use in meta tag http-equiv (undef to skip)
#$charset = 'ISO-8859-1';

## default <body> tag
$body = '<body>';

## number of entries on each TOC page
$toc_on_page = 10;

## use progress bar
$progress_bar = 1;

## content hight for each slide
$content_hight = "70%";

## end of default values for the presentation
##############################################################################

## globals
my $last_toc_title;
my %page_data;
my %overview_data;

##############################################################################
## reading user input from $infos
##
@PARAM = @ARGV; # we keep this for backward compatibility with an old version
                # of the slidemaker tool
                #when the parameters were in Makefile or make.bat

# read parameters from infos.txt and put them in @PARAM
if (open(INFOS, $infos)) {
        print STDOUT "--- Reading parameters file $infos ---\n";
        local(@file,$counter);
        $counter = 0;
        @file = <INFOS>;
        @PARAM = ();
        do {
                if ($file[0] && $file[0] =~ /^[^#\n\r]/) {
                        $file[0] =~ s/\n//;    # remove UNIX \n 
                        $file[0] =~ s/\r//;    # remove WINDOWS \r    
                        $file[0] =~ s/ *= */=/;
                        $PARAM[$counter++] = $file[0];
                        print "$file[0]\n";
                }
        } while (shift(@file));
}
## @PARAM is now a table with the user preferences for his presentation

## process arguments
## each preset variable is now re-attributed using the user preferences
foreach (@PARAM) {
        my ($var,$value) = split(/ *= */,$_,2);
        $value=~s/'/\\'/g;
        $cmd="\$$var = \'$value\';";
        if ($value) {
                eval($cmd) || die "problem with eval of: $cmd";
        } else {
                die "no value defined for $var";
        }
}

## use charset

if ($charset) {
        $http_equiv='<meta http-equiv="Content-type" content="text/html; charset='.$charset.'">';
} else {
        $http_equiv='';
}

##############################################################################
## read the raw html presentation
##

## copy file in memory
my $sep = $/;
$/ = undef;
open(ALL, $all) || die "Error: Cannot open file: $all";
my $buf = <ALL>;
close(ALL);
$/ = $sep;

## Remove comments from the raw presentation
## they do not need to show up on the slides
$buf =~ s/<!--.*?-->//sgo;

## the slidemaker tool assumes that each slide is self contained between 2 sets of h1 tags
## if not it will generate a rather weird output
## split using <h1...> and </h1...> as separator (ignores attributes!)
## h1 or H1 can be used
@table = split(/<\/?[hH]1[^>]*>/, $buf);

## compute the total number of slides
$total = $#table / 2;
if ($#table % 2 != 0) {
        $total = ($#table +1)/2;
}

##
## raw presentation has been read successfully
##############################################################################

##############################################################################
## processing the slides
 
print STDOUT "\n--- Processing $total slides ---\n"; 

## generate the header table of content of the presentation
## which is also the first page of the talk
&openOverview($overview);

## start the slide count so we can number them
$slideCount = 1;

## pre-load template slides using $template dir
Text::FastTemplate->defaults(
                path => [ $template ]
        );

Text::FastTemplate->preload( [
                { file => 'slide.html', key => 'slide' },
                { file => 'overview.html', key => 'overview' },
        ]);

## unroll relative anchors (#something) into links with slides

my %anchor_on_slide;

## step 1: record anchors
for($i=0; $i<$total; $i++) {
        my $tmp = $table[($i*2)].$table[($i*2)+1];
        while ($tmp =~ s,<a +name="*([^>"]+)"*>,,i) {
                $anchor_on_slide{$1}=($i+1);
                print "\tslide ",($i+1)," anchor: $1\n" if ($debug);
        }
}

## step 2: fix links
for($i=0; $i<$total; $i++) {
        foreach (keys %anchor_on_slide) {
                $table[($i*2)] =~ s,href="*#$_"*>,href="slide$anchor_on_slide{$_}\.html#$_">,gi;
        }
}

## @table is the array containing each slide with its title
## for each slide to be generated
## we delete each slide and its title when generated
## so that the current slide and its title are always at $table[0] (for the title)
## and $table[1] (for the slide content)

undef $prev_title;
undef $next_title;

do {

        ## get rid of the first element contained by the raw presentation array
        shift(@table);
        ## then $table[0] is the title of the slide to be generated
        $table[0] =~ s/\n+/ /g;    ## replace return character by a white space 
        $table[0] =~ s/\r+/ /g;    ## replace lf character by a white space 
        $table[0] =~ s/ +/ /g;     ## concatenate several white spaces to only one
        $table[0] =~ s/^ //;       ## remove all the starting white spaces in the title
        $table[0] =~ s/ $//;       ## remove all trailing white spaces in the title
        ## $slideTitle preserves link(s) in the title
        $slideTitle = $table[0];
        ## need to check if the title contains any anchor
        ## if so it needs to be removed
        ## because the title is being used in the table of content to link to the corresponding slide
        $table[0] = remove_anchor($table[0]);

        ## grab next slide title $table[2] (if there's a next slide)
        ## to be able to use in the 'next' navigation button
        ## keep in mind that $table[1] contains the slide corresponding to the title $table[0]
        if ($table[2]) {
                $next_title= remove_anchor($table[2]);
        }

        ## the current slide content is stored $table[1]
        ## there is an attempt to make sure it's clean HTML
        ## Pierre Fillault's note: use same piece of as used in http://www.w3.org/Web/Tools/CvsCommitScripting
        ## to make use of the validation service
        $slideContent = &clean_html($table[1]) ;

        ## extract slide Sub Title <h2>
        undef $slideSubTitle;
        if ($slideContent =~ s/<[hH]2[^>]*>(.+)<\/[hH]2[^>]*>//sm) {
                $slideSubTitle=remove_anchor($1);
        }

        ## add the title of the current slide to the table of content
        &addTitle($slideTitle,$slideSubTitle,$slideCount);

        ## generate the current slide
        ## parameters are:
        ## title of the slide, its content, the slide number, the title of the previous slide and the title of the next slide
        &createSlide($slideTitle,$slideSubTitle,$slideContent ,$slideCount++,$prev_title,$next_title);

        ## save the title of the previous slide to be displayed in the 'previous' navigation button
        $prev_title=remove_anchor($table[0]);
}
## process the next slide 
while (shift(@table));

## close the table of content
&closeOverview;

## generate more toc with the all the style sheets
## as there's no way of loading a style sheet
## except dynamically, but that would be slow
## and would not work on all platforms (ie would fail on Joe's laptop)
&generateTOC;


print STDOUT "--- Finished ---\n";
exit 0;
##
## end of the slidemaker main program
##############################################################################


##############################################################################
## generate the header of the table of content

sub openOverview 
{
        ## open the file to write to
        open(FOO, ">$_[0].html") || die "can't open $_[0].html: $!";

        ## the style sheet used in the table of content is
        $stylelink = "";
        ## here is the standard style sheet
        $stylelink .= "<link href=\"$cssStandard\" rel=\"stylesheet\" type=\"text/css\" title=\"Talk\" media=\"screen\">";

        %overview_data = (
                doctype => $doctype,
                title => $title,
                http_equiv => $http_equiv,
                stylelink => $stylelink,
                body => $body,

                logoLink => $logoLink,
                logoFile => $logoFile,
                logoAlt => $logoAlt,
                logoLink2 => $logoLink2,
                logoFile2 => $logoFile2,
                logoAlt2 => $logoAlt2,

                talkTitle => $talkTitle,
                talkSubTitle => $talkSubTitle,

                content_hight => $content_hight,

                author => $author,
                authorUrl => $authorUrl,
                author2 => $author2,
                authorUrl2 => $authorUrl2,

                date => $date,

                toc => $loc_toc,
        );

}
##
## the beginning of the table of content has been generated and saved
##############################################################################

##############################################################################
## generate the footer of the table of content

sub closeOverview
{
        $overview_data{slide_html} = make_progress_bar(0,$total);
        $overview_data{toc_entries} = [ @toc_entries ];

        my $page= new Text::FastTemplate key => 'overview';
        print FOO $page->output( \%overview_data );

        close(FOO); 
}
##
## the toc has been completed and saved
##############################################################################

##############################################################################
## add an item in the toc

sub addTitle 
{
        my ($title,$subtitle,$nr) = @_;
        $title =~ s/\r//ig;      # remove the windows CR+LF 
        $title =~ s/<[^>]+>//g;

        if (! $title) {
                return 1;
        }

        # split TOC entries to multiple pages

        if ($nr % $toc_on_page == 0) {
                my $toc_nr=int($nr/$toc_on_page);

                $item = {
                        pre_html => $pre_ul,
                        accesskey => " ",       # space
                        href => "index-toc$toc_nr.html",
                        title => "...",
                        post_html => $post_ul,
                        more => 1,      # use style for more pages link (...)
                };
                push @toc_entries, $item;

                &closeOverview;
                undef @toc_entries;
                &openOverview("$overview-toc$toc_nr");
                $last_toc_title='';
        }

        $pre_ul=$post_ul='';
        if ($last_toc_title eq $title) {
                $title = $subtitle;
                $pre_ul='<ul>';
                $post_ul='</ul>';
        } else {
                $last_toc_title=$title;
        }

        # add accesskey for first 9 slides (`1' - `9') or just for first
        # TOC page, and tabindex for all slides
        if ($nr < 10 && $nr < $toc_on_page) {
                $item = {
                        pre_html => $pre_ul,
                        accesskey => "$nr",
                        tabindex => "$nr",
                        href => "slide$nr.html",
                        title => $title,
                        post_html => $post_ul,
                        more => 0,
                };
                push @toc_entries,$item;
        } else {
                $item = {
                        pre_html => $pre_ul,
                        tabindex => "$nr",
                        href => "slide$nr.html",
                        title => $title,
                        post_html => $post_ul,
                };
                push @toc_entries,$item;
        }
}
##
##############################################################################

##############################################################################
## generate the current slide

sub createSlide 
{

        # parameters are respectively the slide title, its content,
        # its number, the next slide title and the previous slide title

        my ($title,$subtitle,$content,$nr,$prev_title,$next_title) = @_;

        if (! $title) {
                return 1;
        }

        # work the slide title, the previous and next titles
        chomp $title;
        $title =~ s/\r//ig;      # remove the windows CR+LF 
        $next_title =~ s/\r//ig; 
        $prev_title =~ s/\r//ig;

        # Remove any tags from the prev & next titles
        $next_title =~ s/<[^>]+>//g;
        $prev_title =~ s/<[^>]+>//g;
        $title =~ s/<[^>]+>//g;

        # Replace double quotes
#       $title =~ s/"/&#34;/g;
        $next_title =~ s/"/&#34;/g;
        $prev_title =~ s/"/&#34;/g;

        # work the slide content
        $content =~ s/<\/body>//i; # remove if any
        $content =~ s/<\/html>//i; # remove if any

        $status = sprintf "Slide %2d: %s %s\n", $nr, $title, $subtitle;
        $status =~ s/<[^>]+>//g;
        print STDOUT $status;

        &verify_html($content);    # check the html

        ## write to the slide
        open(SLIDE, ">slide$nr.html") || die "can't save slide$nr.html: $!";

        my $toc_link = "$overview\.html";

        ## initialization of the navigation links
        my $next_link = "";
        my $prev_link = "";

        if ($nr>1) {
                $prev_link = "slide".($nr-1).".html";
#       } else {
#       ## add a link back to the toc for the first slide --CMN 19991102
#               $prev_link = "$overview\.html";
        }

        if ($nr != $total) {
                $next_link = "slide".($nr+1).".html";
        }

        $stylelink = "";
        # here is the standard style sheet
        $stylelink .= "<link href=\"$cssStandard\" rel=\"stylesheet\" type=\"text/css\" title=\"Talk\">";

        my $slide_html=make_progress_bar($nr,$total);

        %page_data = (
                doctype => $doctype,
                talkTitle => $talkTitle,
                title => $title,
                subtitle => $subtitle,
                http_equiv => $http_equiv,
                stylelink => $stylelink,
                body => $body,

                logoLink => $logoLink,
                logoFile => $logoFile,
                logoAlt => $logoAlt,
                logoLink2 => $logoLink2,
                logoFile2 => $logoFile2,
                logoAlt2 => $logoAlt2,


                content_hight => $content_hight,
                content => $content,

                prev_link => $prev_link,
                toc_link => $toc_link,
                next_link => $next_link,
                prev_title => $prev_title,
                next_title => $next_title,

                author => $author,
                authorUrl => $authorUrl,
                author2 => $author2,
                authorUrl2 => $authorUrl2,

                date => $date,

                slide_html => $slide_html,

        );

        my $page= new Text::FastTemplate key => 'slide';
        print SLIDE $page->output( \%page_data );

        close(SLIDE);
        return 0;
}

##############################################################################
## generate all the toc of contents needed for each css choosen by the user
## the default toc is not numbered so it can be served by a request to '/'
## (ie it remains Overview.html whereas the other toc are called Overview_#.html)

sub generateTOC {

        ## read the general toc
        open(FOO, "<$overview.html"); 
        @TOC = <FOO>;
        close(FOO);
        $toc = "@TOC";

        ## for each user CSS file
        ## starting after the default css
        for ($css=1;$css<$nbCssStandard;$css++) {

                ## create new TOC
                $newTOC = $toc;

                ## the links on the toc need also to be modified
                ## to link to the correct slides
                $newTOC =~ s/<a accesskey=\"(\d)\" tabindex=\"(\d+)\" href=\"slide(\d+)-\d+\.html\">/<a accesskey=\"$1\" tabindex=\"$2\" href=\"slide$3-$css\.html">/ig;
                $newTOC =~ s/<a tabindex=\"(\d+)\" href=\"slide(\d+)-\d+\.html\">/<a tabindex=\"$1\" href=\"slide$2-$css\.html">/ig;

                ## write to new TOC
                $outfile = $overview."-".$css.".html";
                open(OUT, ">$outfile");
                print OUT $newTOC;
                close(OUT)
        }


}

##############################################################################
# check that the html of the slide 
# is correct (ALT tags, ...)
# This procedure produces only warning
sub verify_html {

    if ($_[0] =~ /<img([^>]*)>/im) {
        if (!($1 =~ /ALT=/im)) {
            print STDOUT "WARNING: <IMG> without ALT\n";
            print STDOUT "         <IMG$1>\n" ;
        }
    }
}

##############################################################################
# clean the html of the slide
# remove all <div class="comment">blabla</div>
sub clean_html {
        my $tmp=$_[0];
        $tmp =~ s/<div\s+class\s*=\s*(?:comment[\s>]|\"comment\").*?<\/div>//igs;
        $tmp =~ s,</*font[^>]+>,,ig;
        return $tmp;
}

##############################################################################
# make transparent 1x1 gif (for layout tricks)
sub make_dotgif {
        @dot_gif=(71,73,70,56,57,97,1,0,1,0,128,0,0,192,192,192,0,0,0,33,
                249,4,1,0,0,0,0,44,0,0,0,0,1,0,1,0,0,2,2,68,1,0,59);
        open(GIF,"> $_[0]") || die "can't write gif $_[0]: $!";
        my $dotgif;
        foreach (@dot_gif) {
                $dotgif.=chr($_);
        }
        print GIF $dotgif;
        close(GIF);
}

##############################################################################
# make slide progress bar
sub make_progress_bar {
        my ($nr,$total) = @_;

        my $pcnt_done=int($nr*100/$total);
        my $pcnt_left=100-$pcnt_done;

        if ($progress_bar) {
                my $l=$r="&nbsp;";
                my $t="$nr of $total";
                if ($pcnt_done > 50) {
                        $l=$t;
                } else {
                        $r=$t;
                }
                $html='<table border="0" width="50%" cellpadding="0" cellspacing="0" align="right"><tr><td width="'.$pcnt_done.'%" class="pcnt-done">'.$l.'</td><td width="'.$pcnt_left.'%" class="pcnt-left">'.$r.'</td></tr></table>';
        } else {
                $html="$loc_slide $nr $loc_of $total";
        }

        return $html;
}

##############################################################################
# make slide progress bar
sub remove_anchor {
        my $tmp = $_[0];
        $tmp =~ s/(.*)<A[^>]*>(.*)<\/A>(.*)/$1$2$3/ig;
        return $tmp;
}